Jump to content


Photo

Recovery Fix ISO for Advent Vista & EIsystems


  • Please log in to reply
No replies to this topic

#1 Ben_Mott

Ben_Mott

    IT God

  • Members
  • PipPipPipPipPipPipPip
  • 2,692 posts

Posted 03 July 2008 - 08:00 PM

Link:
3july08
http://support.thete...leReference=521
Ben
.................................................................
Summary
Download a disk image file that will allow you to run the Windows Vista™ recovery program if you cannot start it via the F8 menu on startup.

This disk will start the recovery process on the following makes of computer only:

* Advent
* Ei System
* Philips-Freevents

File Name
FIXDISKV1.zip (201MB)
http://support.thete...leReference=521
More Information
You will need 1 blank CD or DVD to create the disk and it is very important you follow all the steps below to create the disk correctly.

* Click the FIXDISKV1.zip download link and save the file to the desktop
* Once it has finished downloading double click on the zip file
* Click Extract all files on the top menu
* Extract the file to the desktop
* Load your DVD burning software
imgburn is the best google it
* Choose to burn an image
* Insert a blank DVD when prompted and complete the burning process
==========================================================
Detail:
======================

here is a vista PE specially Hacked to repair Avent,EIsystem and Philips vista OS
http://support.thete...4-2af1d2419acb}
the fix is in TGM directory
and it loads from winpeshl.ini in x:\windows\system32
you need to mount it using 2mount.bat
and put a43.exe in there and change the file to load a43.exe file manager instead of fixboot.exe
then you can work with it
the boot.wim is nearly 200mb but when you build the ISo using 6buildiso.bat
it increases to 1.2GB so you need to use -m to change it to DVD instead of CD read previous posts

the TGM directory contains these files:

-----------------------------------
Directory of TGM
=====================


diskpart_CheckLetters2.txt
diskpart_SetRtoActive.txt
FixBoot.exe

msvbvm60.dll
new.cmd
scrrun.dll
SetAutoFailover.cmd
-------------------------------
the fixboot.exe is simply a visual5/6 one button command dialog box to run
the new.cmd file in GUI mode
the new.cmd contains this:
----------------------------
X:\Windows\System32\diskpart.exe /s X:\TGM\diskpart_CheckLetters2.txt


call X:\TGM\setautofailover.cmd /target r: /mainos {default} /disk 0 /partition 1 /nohide


BCDEDIT -set {bootmgr} device partition=R:
BCDEDIT -set {default} device partition=R:
BCDEDIT -set {default} osdevice partition=R:
REM BCDEDIT -set {default} path \windows\system32\Boot\winload.exe
REM BCDEDIT -set {bootmgr} path \windows\system32\Boot\winload.exe

xcopy v:\Bootmgr R:\ /chy
xcopy v:\Boot R:\Boot\ /chey


X:\Windows\System32\diskpart.exe /s X:\TGM\diskpart_SetRtoActive.txt


BCDEDIT -set {bootmgr} device partition=R:
BCDEDIT -set {default} device partition=R:
BCDEDIT -set {default} osdevice partition=R:
-----------------------------------------------
the /s in diskpart.exe means run script file following /s
and /chey in xcopy means
c- copy even with error
h-copy hidden files
e-copy all sub directory and empty files
y- do not prompt user
---------------------------------------
so the other files it relies on are diskpart_CheckLetters2.txt
......................
select disk 0
select partition 1
assign letter=R
select partition 2
assign letter=V
active

.........................
diskpart_SetRtoActive.txt
,,,,,,,,,,,,,,,,,,,,,,,,,,

select disk 0
select partition 1
active
,,,,,,,,,,,,,,,,,,,,,,,,,
SetAutoFailover.cmd
======================================
@echo off

REM
REM Copyright © Microsoft Corporation
REM
REM Description:
REM
REM Sample script to configure the boot configuration data
REM of Windows Vista and WinRE to set auto failover.
REM
REM

:GLOABAL_INIT

setlocal & pushd & set RET=

set SCRIPTNAME=%~n0
set SCRIPTPATH=%~f0
if "%DEBUG%"=="1" (set TRACE=echo) else (set TRACE=REM)

if /i {%1} == {-?} (call :SHOW_USAGE & goto :EOF)
if /i {%1} == {/?} (call :SHOW_USAGE & goto :EOF)

call :MAIN %*

popd & endlocal & set RET=%RET%& set PATH=%PATH%

goto :EOF

REM
REM Main procedure
REM

:MAIN

set BCDEDIT=bcdedit.exe
set DISKPART=diskpart.exe
set DISK=0
set PARTITION=1
set MAINOS={default}

REM
REM Parse command line
REM

call :PARSE %*

REM
REM Check whether bcdedit exists or not
REM

%BCDEDIT% /?>nul

if %errorlevel%==9009 (
call :SHOW_USAGE
goto :EOF
)

if {%TARGET%} == {} (
call :SHOW_USAGE
goto :EOF
)

REM
REM Extract the drive name and root directory from the target
REM
for /f "delims=: tokens=1*" %%I in ("%TARGET%") do (
set DRIVE=%%I:
set WINRE_ROOT_DIR=%%J
)

if {%DRIVE%} == {:} (
call :SHOW_USAGE
goto :EOF
)

if not {%BCDSTORE%} == {} (
set BCDEDIT=%BCDEDIT% -store %BCDSTORE%
)

if {%ISWIM%}=={} (

REM
REM WinRE root directory should be NULL.
REM
if not {%WINRE_ROOT_DIR%}=={} (
echo ERROR: WinRE cannot be installed under a sub directory.
goto :EOF
)

call :CREATE_DIR_BCD_ENTRY

) else (

call :CREATE_WIM_BCD_ENTRY

)

REM
REM Mark this installation as the recovery OS. This recovery OS identifier
REM will be used by other components to enable/disable auto recovery.
REM
%BCDEDIT% -set %WINPE_GUID% custom:46000010 yes

REM
REM Set the recovery sequence
REM

%BCDEDIT% -set %MAINOS% recoverysequence %WINPE_GUID%
%BCDEDIT% -set %MAINOS% recoveryenabled yes

REM
REM Hide partition
REM

if not {%NOHIDE%}=={} (
goto :EOF
)

set TEMP_FILENAME=%SCRIPTNAME%_Temp_DiskPart.txt

echo sel disk %DISK% > %TEMP_FILENAME%
echo sel partition %PARTITION% >> %TEMP_FILENAME%

REM
REM Remove the drive letter for the partition before hiding it.
REM The system will not allow us to remove the drive letter after hiding it.
REM
echo remove >> %TEMP_FILENAME%

if {%GPT%}=={} (
echo set id=27 >> %TEMP_FILENAME%
) else (

REM
REM Set GPT_ATTRIBUTE_PLATFORM_REQUIRED attribute
REM
echo gpt attributes=0x0000000000000001 >> %TEMP_FILENAME%
)

%DISKPART% /s %TEMP_FILENAME%

del %TEMP_FILENAME%

REM
REM Done.
REM

goto :EOF

REM
REM Procedure to parse command line.
REM

:PARSE

if {%1} == {} goto PARSE_DONE

if /i {%1} == {-target} set TARGET=%2&& shift && goto PARSE_NEXT
if /i {%1} == {/target} set TARGET=%2&& shift && goto PARSE_NEXT

if /i {%1} == {-wim} set ISWIM=1&& goto PARSE_NEXT
if /i {%1} == {/wim} set ISWIM=1&& goto PARSE_NEXT

if /i {%1} == {-gpt} set GPT=1&& goto PARSE_NEXT
if /i {%1} == {/gpt} set GPT=1&& goto PARSE_NEXT

if /i {%1} == {-diskpart} set DISKPART=%2&& shift && goto PARSE_NEXT
if /i {%1} == {/diskpart} set DISKPART=%2&& shift && goto PARSE_NEXT

if /i {%1} == {-bcdedit} set BCDEDIT=%2&& goto PARSE_NEXT
if /i {%1} == {/bcdedit} set BCDEDIT=%2&& goto PARSE_NEXT

if /i {%1} == {-bcdstore} set BCDSTORE=%2&& goto PARSE_NEXT
if /i {%1} == {/bcdstore} set BCDSTORE=%2&& goto PARSE_NEXT

if /i {%1} == {-mainos} set MAINOS=%2&& goto PARSE_NEXT
if /i {%1} == {/mainos} set MAINOS=%2&& goto PARSE_NEXT

if /i {%1} == {-partition} set PARTITION=%2&& goto PARSE_NEXT
if /i {%1} == {/partition} set PARTITION=%2&& goto PARSE_NEXT

if /i {%1} == {-disk} set DISK=%2&& goto PARSE_NEXT
if /i {%1} == {/disk} set DISK=%2&& goto PARSE_NEXT

if /i {%1} == {-nohide} set NOHIDE=1&& goto PARSE_NEXT
if /i {%1} == {/nohide} set NOHIDE=1&& goto PARSE_NEXT

:PARSE_NEXT

shift
goto PARSE

:PARSE_DONE

goto :EOF

REM
REM Procedure to create a BCD entry for WinRE installed as a flat directory
REM

:CREATE_DIR_BCD_ENTRY

REM
REM Customize WinRE
REM

echo [LaunchApp] > %TARGET%\windows\system32\winpeshl.ini
echo AppPath=x:%WINRE_ROOT_DIR%\sources\recovery\recenv.exe >> %TARGET%\windows\system32\winpeshl.ini

REM
REM Set BCD
REM {572bcd55-ffa7-11d9-aae0-0007e994107d}, GUID for the WinPE boot entry
REM

set WINPE_GUID={572bcd55-ffa7-11d9-aae0-0007e994107d}

REM
REM Create WinRE boot entry
REM

%BCDEDIT% -create %WINPE_GUID% -d "Windows Recovery Environment" -application OSLOADER
%BCDEDIT% -set %WINPE_GUID% device partition=%DRIVE%
%BCDEDIT% -set %WINPE_GUID% path %WINRE_ROOT_DIR%\windows\system32\boot\winload.exe
%BCDEDIT% -set %WINPE_GUID% osdevice partition=%DRIVE%
%BCDEDIT% -set %WINPE_GUID% systemroot %WINRE_ROOT_DIR%\windows
%BCDEDIT% -set %WINPE_GUID% detecthal yes
%BCDEDIT% -set %WINPE_GUID% nx optin
%BCDEDIT% -set %WINPE_GUID% winpe yes

goto :EOF

REM
REM Procedure to create a BCD entry for WinRE installed as a WIM file
REM

:CREATE_WIM_BCD_ENTRY

REM
REM {ad6c7bc8-fa0f-11da-8ddf-0013200354d8}
REM
set RAMDISK_OPTIONS={ad6c7bc8-fa0f-11da-8ddf-0013200354d8}

REM
REM {572bcd56-ffa7-11d9-aae0-0007e994107d}, GUID for the WinPE boot entry
REM

set WINPE_GUID={572bcd56-ffa7-11d9-aae0-0007e994107d}

REM
REM Create Ramdisk device options for the boot.sdi file
REM
%BCDEDIT% -create %RAMDISK_OPTIONS% -d "Ramdisk Device Options" -device
%BCDEDIT% -set %RAMDISK_OPTIONS% ramdisksdidevice partition=%DRIVE%
%BCDEDIT% -set %RAMDISK_OPTIONS% ramdisksdipath \boot.sdi

REM
REM Create WinRE boot entry
REM

%BCDEDIT% -create %WINPE_GUID% -d "Windows Recovery Environment" -application OSLOADER
%BCDEDIT% -set %WINPE_GUID% device ramdisk=[%DRIVE%]\winre.wim,%RAMDISK_OPTIONS%
%BCDEDIT% -set %WINPE_GUID% path \windows\system32\boot\winload.exe
%BCDEDIT% -set %WINPE_GUID% osdevice ramdisk=[%DRIVE%]\winre.wim,%RAMDISK_OPTIONS%
%BCDEDIT% -set %WINPE_GUID% systemroot \windows
%BCDEDIT% -set %WINPE_GUID% detecthal yes
%BCDEDIT% -set %WINPE_GUID% nx optin
%BCDEDIT% -set %WINPE_GUID% winpe yes

goto :EOF


REM
REM Procedure to show usage information
REM

:SHOW_USAGE

echo.
echo This script configure auto failover settings for the specified WinRE.
echo.
echo Usage:
echo %SCRIPTNAME% /target (WinRE path) [Options]
echo.
echo Options:
echo.
echo /target (drive where WinRE is installed) [required]
echo The drive where WinRE is installed w/o the trailing backslash,
echo e.g., C:
echo.
echo /wim [optional]
echo Specifies that WinRE.wim file is installed on target drive. The script
echo assumes that the name of the WIM file is WinRE.wim and the
echo name of the SDI file is boot.sdi
echo.
echo /partition (partition number of the WinRE drive) [optional]
echo Partition number for the above WinRE drive. By default
echo the script assumes partition number 1.
echo.
echo /disk (disk number of the WinRE drive) [optional]
echo Disk number of the above WinRE drive. By default the script assumes
echo disk number 0.
echo.
echo /gpt [optional]
echo The target disk is a GPT disk. By default the script assumes
echo an MBR disk.
echo.
echo /mainos (guid of the main OS) [optional]
echo Use the specified GUID for the main OS. By default the script
echo assumes the current OS. Note -- always specify this option when
echo running from WinPE. To configure the default OS in BCD specify
echo {default}.
echo.
echo /nohide [optional]
echo Don't hide the winre partition
echo.
echo /bcdedit (Full path to bcdedit.exe) [optional]
echo Use the specified bcdedit.exe. By default the script assumes
echo that bcdedit.exe is in the PATH environment variable.
echo.
echo /bcdstore (Full path to BCD store) [optional]
echo Use the specified BCD store. By default the script assumes
echo the system BCD store.
echo.
echo /diskpart (Full path to diskpart.exe) [optional]
echo Use the specified diskpart.exe. By default the script assumes
echo that diskpart.exe is in the PATH environment variable.
echo.

goto :EOF


============================================================================
the diskpart is in the system32 directory of VistaPE(DVD)